root/docs/docbook-xsl/fo/xep.xsl

Revision 23dea7e00df87480acb58bb3398283c2bb227949, 5.9 kB (checked in by Theo Schlossnagle <jesus@omniti.com>, 7 years ago)

pull docs into master

  • Property mode set to 100644
Line 
1 <?xml version='1.0'?>
2 <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
3                 xmlns:fo="http://www.w3.org/1999/XSL/Format"
4                 xmlns:rx="http://www.renderx.com/XSL/Extensions"
5                 version='1.0'>
6
7 <!-- ********************************************************************
8      $Id: xep.xsl,v 1.22 2005/06/28 07:49:51 xmldoc Exp $
9      ********************************************************************
10      (c) Stephane Bline Peregrine Systems 2001
11      Implementation of xep extensions:
12        * Pdf bookmarks (based on the XEP 2.5 implementation)
13        * Document information (XEP 2.5 meta information extensions)
14      ******************************************************************** -->
15
16 <!-- FIXME: Norm, I changed things so that the top-level element (book or set)
17      does not appear in the TOC. Is this the right thing? -->
18
19 <xsl:template name="xep-document-information">
20   <rx:meta-info>
21     <xsl:variable name="authors" select="(//author|//editor|//corpauthor|//authorgroup)[1]"/>
22     <xsl:if test="$authors">
23       <xsl:element name="rx:meta-field">
24         <xsl:attribute name="name">author</xsl:attribute>
25         <xsl:attribute name="value">
26           <xsl:choose>
27             <xsl:when test="$authors[self::authorgroup]">
28               <xsl:call-template name="person.name.list">
29                 <xsl:with-param name="person.list" select="$authors/*[self::author|self::corpauthor|self::othercredit|self::editor]"/>
30               </xsl:call-template>
31             </xsl:when>
32             <xsl:when test="$authors[self::corpauthor]">
33               <xsl:value-of select="$authors"/>
34             </xsl:when>
35             <xsl:otherwise>
36               <xsl:call-template name="person.name">
37                 <xsl:with-param name="node" select="$authors"/>
38               </xsl:call-template>
39             </xsl:otherwise>
40           </xsl:choose>
41         </xsl:attribute>
42       </xsl:element>
43     </xsl:if>
44
45     <xsl:variable name="title">
46       <xsl:apply-templates select="/*[1]" mode="label.markup"/>
47       <xsl:apply-templates select="/*[1]" mode="title.markup"/>
48     </xsl:variable>
49
50     <xsl:element name="rx:meta-field">
51       <xsl:attribute name="name">creator</xsl:attribute>
52       <xsl:attribute name="value">
53         <xsl:text>DocBook XSL Stylesheets V</xsl:text>
54         <xsl:value-of select="$VERSION"/>
55       </xsl:attribute>
56     </xsl:element>
57
58     <xsl:element name="rx:meta-field">
59       <xsl:attribute name="name">title</xsl:attribute>
60       <xsl:attribute name="value">
61         <xsl:value-of select="$title"/>
62       </xsl:attribute>
63     </xsl:element>
64
65     <xsl:if test="//keyword">
66       <xsl:element name="rx:meta-field">
67         <xsl:attribute name="name">keywords</xsl:attribute>
68         <xsl:attribute name="value">
69           <xsl:for-each select="//keyword">
70             <xsl:value-of select="."/>
71             <xsl:if test="position() != last()">
72               <xsl:text>, </xsl:text>
73             </xsl:if>
74           </xsl:for-each>
75         </xsl:attribute>
76       </xsl:element>
77     </xsl:if>
78
79     <xsl:if test="//subjectterm">
80       <xsl:element name="rx:meta-field">
81         <xsl:attribute name="name">subject</xsl:attribute>
82         <xsl:attribute name="value">
83           <xsl:for-each select="//subjectterm">
84             <xsl:value-of select="."/>
85             <xsl:if test="position() != last()">
86               <xsl:text>, </xsl:text>
87             </xsl:if>
88           </xsl:for-each>
89         </xsl:attribute>
90       </xsl:element>
91     </xsl:if>
92   </rx:meta-info>
93 </xsl:template>
94
95 <!-- ********************************************************************
96      Pdf bookmarks
97      ******************************************************************** -->
98
99 <xsl:template match="*" mode="xep.outline">
100   <xsl:apply-templates select="*" mode="xep.outline"/>
101 </xsl:template>
102
103 <xsl:template match="set|book|part|reference|preface|chapter|appendix|article
104                      |glossary|bibliography|index|setindex
105                      |refentry|refsynopsisdiv
106                      |refsect1|refsect2|refsect3|refsection
107                      |sect1|sect2|sect3|sect4|sect5|section"
108               mode="xep.outline">
109   <xsl:variable name="id">
110     <xsl:call-template name="object.id"/>
111   </xsl:variable>
112   <xsl:variable name="bookmark-label">
113     <xsl:apply-templates select="." mode="object.title.markup"/>
114   </xsl:variable>
115
116   <!-- Put the root element bookmark at the same level as its children -->
117   <!-- If the object is a set or book, generate a bookmark for the toc -->
118
119   <xsl:choose>
120     <xsl:when test="parent::*">
121       <rx:bookmark internal-destination="{$id}">
122         <rx:bookmark-label>
123           <xsl:value-of select="$bookmark-label"/>
124         </rx:bookmark-label>
125         <xsl:apply-templates select="*" mode="xep.outline"/>
126       </rx:bookmark>
127     </xsl:when>
128     <xsl:otherwise>
129       <xsl:if test="$bookmark-label != ''">
130         <rx:bookmark internal-destination="{$id}">
131           <rx:bookmark-label>
132             <xsl:value-of select="$bookmark-label"/>
133           </rx:bookmark-label>
134         </rx:bookmark>
135       </xsl:if>
136
137       <xsl:variable name="toc.params">
138         <xsl:call-template name="find.path.params">
139           <xsl:with-param name="table" select="normalize-space($generate.toc)"/>
140         </xsl:call-template>
141       </xsl:variable>
142       <xsl:if test="contains($toc.params, 'toc')
143                     and set|book|part|reference|section|sect1|refentry
144                         |article|bibliography|glossary|chapter
145                         |appendix">
146         <rx:bookmark internal-destination="toc...{$id}">
147           <rx:bookmark-label>
148             <xsl:call-template name="gentext">
149               <xsl:with-param name="key" select="'TableofContents'"/>
150             </xsl:call-template>
151           </rx:bookmark-label>
152         </rx:bookmark>
153       </xsl:if>
154       <xsl:apply-templates select="*" mode="xep.outline"/>
155     </xsl:otherwise>
156   </xsl:choose>
157 </xsl:template>
158
159 </xsl:stylesheet>
Note: See TracBrowser for help on using the browser.