root/configure.in

Revision 39f7fec10a027d9f03e3c662a750b0c7432c6833, 14.3 kB (checked in by Theo Schlossnagle <jesus@omniti.com>, 4 years ago)

readdir_r (or rather Solaris) is the suck.

  • Property mode set to 100755
Line 
1 AC_INIT(src/noitd.c)
2
3 node=`hostname | cut -f1 -d '.' | tr '[A-Z]' '[a-z]'`
4 if test -f ".configure.$node"; then
5         echo "***********************************************************"
6         echo "* Loading node specific configure settings for $node."
7         echo "***********************************************************"
8         . ./.configure.$node
9 fi
10
11 AC_CANONICAL_HOST
12 AC_CONFIG_HEADER(src/noit_config.h)
13 AC_CONFIG_HEADER(src/jlog/jlog_config.h)
14
15 AC_PROG_CC
16 AC_C_INLINE
17 AC_C_BIGENDIAN
18 AC_PROG_CPP
19 AC_PROG_RANLIB
20 AC_PROG_INSTALL
21 AC_PROG_LN_S
22 AC_PATH_PROG(AR, ar)
23 AC_PATH_PROGS(PERL, perl)
24 AC_PATH_PROGS(XSLTPROC, xsltproc)
25 AC_PATH_PROGS(XMLLINT, xmllint)
26 AC_PATH_PROGS(JAVA, java)
27 AC_PATH_PROGS(JAVAC, javac)
28 AC_PATH_PROGS(JAR, jar)
29 AC_PATH_PROG(NROFF, nroff)
30 AC_SUBST(PERL)
31
32 if test "x$CC" = "xgcc" ; then
33   CFLAGS="$CFLAGS -g -Wall"
34 else
35   CFLAGS="$CFLAGS -g"
36 fi
37
38 CPPFLAGS="$CPPFLAGS "'-I$(top_srcdir)/src'
39
40 case $host in
41 *-*-darwin*)
42         PICFLAGS="-fPIC"
43         MODULELD="$CC -bundle -flat_namespace -undefined suppress"
44         SHLD="$CC -dynamiclib -flat_namespace -undefined suppress"
45         MODULEEXT=bundle
46         RLDFLAG="-Wl,--rpath="
47         ;;
48 *-*-solaris*)
49         AC_MSG_CHECKING([32 or 64 bit Solaris assembly])
50         if test -n "`echo $CFLAGS | grep m64`"; then
51                 AC_MSG_RESULT([64])
52                 ATOMIC_OBJS="noit_atomic_sol_x86_64.o"
53         else
54                 AC_MSG_RESULT([32])
55                 ATOMIC_OBJS="noit_atomic_sol_x86_32.o"
56         fi
57         if test "x$CC" != "xgcc" ; then
58                 CFLAGS="$CFLAGS -mt"
59         fi
60         PICFLAGS="-Kpic"
61         MODULELD="$CC -G"
62         SHLD="$CC -G"
63         MODULEEXT=so
64         RLDFLAG="-R"
65         WHOLE_ARCHIVE="-Wl,-z -Wl,allextract"
66         NOWHOLE_ARCHIVE="-Wl,-z -Wl,defaultextract"
67         ;;
68 *-*-openbsd*)
69         PICFLAGS="-fpic"
70         LDFLAGS="$LDFLAGS -Wl,-E"
71         MODULELD="$CC -shared"
72         SHLD="$CC -shared"
73         MODULEEXT=so
74         LDFLAGS="$LDFLAGS -L/usr/local/lib"
75         CFLAGS="$CFLAGS -I/usr/local/include"
76         RLDFLAG="-Wl,--rpath="
77         WHOLE_ARCHIVE="-Wl,--whole-archive"
78         NOWHOLE_ARCHIVE="-Wl,--no-whole-archive"
79         ;;
80 *-*-linux*)
81         LDFLAGS="$LDFLAGS -Wl,-E"
82         CPPFLAGS="$CPPFLAGS"
83         PICFLAGS="-fpic"
84         MODULELD="$CC -shared"
85         SHLD="$CC -shared"
86         MODULEEXT=so
87         RLDFLAG="-Wl,--rpath="
88         WHOLE_ARCHIVE="-Wl,--whole-archive"
89         NOWHOLE_ARCHIVE="-Wl,--no-whole-archive"
90         ;;
91 *-*-freebsd*)
92         PICFLAGS="-fpic"
93         MODULELD="$CC -shared"
94         LDFLAGS="$LDFLAGS -export-dynamic -L/usr/local/lib"
95         CFLAGS="$CFLAGS -I/usr/local/include"
96         MODULEEXT=so
97         RLDFLAG="-Wl,--rpath="
98         ;;
99 *)
100         PICFLAGS="-fpic"
101         MODULELD="$CC -shared"
102         MODULEEXT=so
103         RLDFLAG="-Wl,--rpath="
104         ;;
105 esac
106 AC_SUBST(SHLD)
107 AC_SUBST(RLDFLAG)
108 AC_SUBST(MODULELD)
109 AC_SUBST(MODULEEXT)
110 AC_SUBST(WHOLE_ARCHIVE)
111 AC_SUBST(NOWHOLE_ARCHIVE)
112 AC_SUBST(ATOMIC_OBJS)
113 AC_DEFINE_UNQUOTED(MODULEEXT, "$MODULEEXT", [module extension])
114 AC_MSG_CHECKING([enable build/install of the Java IEP bits])
115
116 if test -z "$ac_cv_path_JAVA" ; then
117         AC_MSG_RESULT([no])
118 else
119         JAVAPARTS=java
120         AC_MSG_RESULT([yes])
121 fi
122 AC_SUBST(JAVAPARTS)
123
124 NOIT_SVNVERSION=`svnversion`
125 AC_DEFINE_UNQUOTED(NOIT_SVNVERSION, "$NOIT_SVNVERSION", [svn version from wc])
126
127 # Checks for data types
128 AC_CHECK_SIZEOF(char, 1)
129 AC_CHECK_SIZEOF(short int, 2)
130 AC_CHECK_SIZEOF(int, 4)
131 AC_CHECK_SIZEOF(long int, 4)
132 AC_CHECK_SIZEOF(long long int, 8)
133 AC_CHECK_SIZEOF(void *, 1)
134
135 AC_CHECK_LIB(z, compress2, , [AC_MSG_ERROR(*** zlib is required ***)])
136 AC_CHECK_LIB(rt, sem_init, , )
137 AC_CHECK_LIB(posix4, sem_wait, , )
138 AC_CHECK_LIB(pthread, pthread_create, , )
139 AC_CHECK_FUNC(uuid_generate, , [
140   AC_MSG_WARN([uuid_generate not available])
141   AC_CHECK_LIB(uuid, uuid_generate, , [AC_MSG_ERROR(*** uuid is required ***)])])
142
143 # Some libraries provide an unparse_lower command
144 # we use that, so if it isn't present, we'll need
145 # to implement it.
146 AC_CHECK_FUNC(uuid_unparse_lower, [AC_DEFINE(HAVE_UUID_UNPARSE_LOWER)], )
147 AC_CHECK_LIB(util, openpty, , )
148 AC_CHECK_LIB(termcap, tputs, , )
149 AC_CHECK_LIB(curses, clear, , [AC_MSG_ERROR([curses not found, but required])])
150
151 CPPFLAGS="$CPPFLAGS `pcre-config --cflags`"
152 LDFLAGS="$LDFLAGS `pcre-config --libs`"
153 AC_CHECK_LIB(pcre, pcre_compile, ,
154         [
155                 AC_MSG_ERROR([libpcre not found, but required])
156         ]
157 )
158 AC_CHECK_LIB(crypto, ERR_load_CRYPTO_strings, ,
159         [
160                 AC_MSG_ERROR([libcrypto not found, but required])
161         ]
162 )
163 AC_CHECK_LIB(ssl, SSL_library_init, ,
164         [
165                 AC_MSG_ERROR([libssl not found, but required])
166         ]
167 )
168
169 old_LIBS=$LIBS
170 old_CFLAGS=$CFLAGS
171 AC_CHECK_LIB(pq, PQconnectdb,
172         [
173                 LIBS="$LIBS -lpq"
174                 PGLIBS="$LIBS"
175                 AC_SUBST(PGLIBS)
176         ],
177         [
178                 AC_MSG_ERROR([libpq required])
179         ]
180 )
181
182 AC_MSG_CHECKING([libpq includes])
183 PQICFLAGS=`pg_config --includedir`
184 if test -n "$PQICFLAGS" ; then
185   CFLAGS="$CFLAGS -I$PQICFLAGS"
186 fi
187
188 AC_TRY_LINK([
189         #include <libpq-fe.h>
190         ],
191         [ PGconn *dbh = PQconnectdb(""); ],
192         [],
193         [ AC_MSG_ERROR([Cannot compile/link against libpq]) ]
194 )
195 PGCFLAGS=$CFLAGS
196 AC_SUBST(PGCFLAGS)
197
198 AC_CHECK_HEADERS(mysql.h mysql/mysql.h)
199
200 if test "$ac_cv_header_mysql_h" = "no" -a "$ac_cv_header_mysql_mysql_h" = "no" ; then
201         AC_MSG_WARN([No libmysqlclient, skipping mysql module])
202         AC_SUBST(MYCFLAGS)
203         AC_SUBST(MYLIBS)
204 else
205         LIBS=$old_LIBS
206         CFLAGS=$old_CFLAGS
207        
208         if test -z "$MYLIBS" ; then
209           MYLIBS="-lmysqlclient_r -lz -lssl -lcrypto"
210         fi
211        
212         old_CFLAGS=$CFLAGS
213         old_LIBS=$LIBS
214         CFLAGS="$CFLAGS $MYCFLAGS"
215         LIBS="$MYLIBS"
216        
217         AC_CHECK_FUNC(mysql_real_connect,
218                 [
219                         BUILD_MODULES="$BUILD_MODULES mysql.$MODULEEXT"
220                         MYCFLAGS="$CFLAGS"
221                         MYLIBS="$LIBS"
222                         AC_SUBST(MYCFLAGS)
223                         AC_SUBST(MYLIBS)
224                 ],
225                 [
226                         AC_MSG_WARN([No libmysqlclient, skipping mysql module])
227                         AC_SUBST(MYCFLAGS)
228                         AC_SUBST(MYLIBS)
229                 ]
230         )
231        
232        
233         LIBS=$old_LIBS
234         CFLAGS=$old_CFLAGS
235 fi
236
237 ########
238 #
239 # CHECK FOR VARIOUS MODULE CRITERIA
240 # We don't track the libs themselves, as we'll just explictly link
241 # against the in the makefile if we enable them to build (by adding
242 # them to the BUILD_MODULES list).
243 #
244 ########
245
246 # Should we build snmp checks?
247 SAVELIBS="$LIBS"
248 AC_CHECK_LIB(netsnmp, snmp_sess_open,
249         [
250                 BUILD_MODULES="$BUILD_MODULES snmp.$MODULEEXT"
251         ],
252         [
253                 AC_MSG_WARN([No libnetsnmp, skipping snmp module])
254         ]
255 )
256 LIBS="$SAVELIBS"
257
258 # Should we build ssh2 checks?
259 SAVELIBS="$LIBS"
260 AC_CHECK_LIB(ssh2, libssh2_session_init_ex,
261         [
262                 BUILD_MODULES="$BUILD_MODULES ssh2.$MODULEEXT"
263         ],
264         [
265                 AC_MSG_WARN([No libssh2, skipping ssh2 module])
266         ]
267 )
268 LIBS="$SAVELIBS"
269
270 AC_MSG_CHECKING([libxml2 cflags])
271 XML2CFLAGS=`xml2-config --cflags`
272 CFLAGS="$CFLAGS $XML2CFLAGS"
273 AC_MSG_RESULT([$XML2CFLAGS])
274
275 AC_MSG_CHECKING([libxml2 libs])
276 XML2LIBS=`xml2-config --libs`
277 LIBS="$LIBS $XML2LIBS"
278 AC_MSG_RESULT([$XML2LIBS])
279
280 AC_CHECK_FUNC(xmlParseDocument, , [AC_MSG_ERROR(*** libxml2 is required ***)])
281
282 AC_MSG_CHECKING([libxslt cflags])
283 XSLTCFLAGS=`xslt-config --cflags`
284 CFLAGS="$CFLAGS $XSLTCFLAGS"
285 AC_MSG_RESULT([$XSLTCFLAGS])
286
287 AC_MSG_CHECKING([libxslt libs])
288 XSLTLIBS=`xslt-config --libs`
289 LIBS="$LIBS $XSLTLIBS"
290 AC_MSG_RESULT([$XSLTLIBS])
291
292 AC_CHECK_FUNC(xsltParseStylesheetDoc, , [AC_MSG_ERROR(*** libxslt is required ***)])
293
294 APRPREFIX="`apr-1-config --prefix`"
295 AC_SUBST(APRPREFIX)
296 AC_MSG_RESULT([$APRPREFIX])
297
298 AC_MSG_CHECKING([libapr cflags])
299 APRCFLAGS="`apr-1-config --cflags --cppflags --includes`"
300 AC_SUBST(APRCFLAGS)
301 AC_MSG_RESULT([$APRCFLAGS])
302
303 AC_MSG_CHECKING([libapr libs])
304 APRLIBS="`apr-1-config --link-ld --ldflags --libs`"
305 AC_SUBST(APRLIBS)
306 AC_MSG_RESULT([$APRLIBS])
307
308 AC_TRY_LINK([],
309         [ issetugid(); ],
310         [ ac_cv_libc_defines_issetugid="yes" ],
311         [ ac_cv_libc_defines_issetugid="no" ]
312 )
313 if test "x$ac_cv_libc_defines_issetugid" = "xyes" ; then
314         AC_DEFINE(HAVE_ISSETUGID)
315 fi
316
317 AC_MSG_CHECKING([whether sem_init works])
318 AC_TRY_RUN(
319         [
320 #include <semaphore.h>
321 int main(void){sem_t s;return (0 != sem_init(&s,0,0));}
322         ],
323         [
324                 AC_MSG_RESULT(yes)
325                 AC_DEFINE(WORKING_SEM_INIT)
326         ],
327         [
328                 AC_MSG_RESULT(no)
329                 AC_MSG_WARN([****** sem_init() is broken, I'll implement one myself.])
330         ]
331 )
332
333 AC_FUNC_STRFTIME
334 AC_CHECK_FUNCS(ssetugid strlcpy strnstrn openpty inet_pton inet_ntop getopt \
335                poll)
336
337 # Checks for header files.
338 AC_CHECK_HEADERS(sys/file.h sys/types.h dirent.h sys/param.h fcntl.h errno.h limits.h \
339                  sys/resource.h pthread.h semaphore.h pwd.h stdio.h stdlib.h string.h \
340                  ctype.h unistd.h time.h pty.h sys/stat.h sys/event.h libkern/OSAtomic.h \
341                  term.h termio.h termios.h curses.h sys/cdefs.h grp.h netinet/in_systm.h \
342                  sys/ioctl_compat.h sys/filio.h util.h sys/time.h sys/mman.h \
343                  stropts.h sys/stream.h alloca.h sys/wait.h)
344
345 AC_CHECK_FUNCS(getpwnam_r)
346 GETPWNAM_R_POSIX
347 AC_CHECK_FUNCS(getgrnam_r)
348 GETGRNAM_R_POSIX
349
350 AC_MSG_CHECKING(for tputs() function final argument type)
351 AC_EGREP_CPP([tputs.*[(][       ]*char[         ]*[)]],
352                 [#if defined(HAVE_TERM_H)
353                  #include <term.h>
354                  #endif
355                  #if defined(HAVE_CURSES_H)
356                  #include <curses.h>
357                  #endif],
358                 [AC_MSG_RESULT(char)
359                  AC_DEFINE(TPUTS_TAKES_CHAR)],
360                 [AC_MSG_RESULT(not char)])
361
362 AC_CACHE_CHECK([for epoll support], ac_cv_have_epoll, [
363         AC_TRY_LINK(
364                 [ #include <sys/types.h> ],
365                 [ u_int a; a = epoll_create(); ],
366                 [ ac_cv_have_epoll="yes" ],
367                 [ ac_cv_have_epoll="no" ]
368         )
369 ])
370 if test "x$ac_cv_have_epoll" = "xyes" ; then
371         AC_DEFINE(HAVE_EPOLL)
372         EVENTER_OBJS="$EVENTER_OBJS eventer_epoll_impl.o"
373         AC_DEFINE_UNQUOTED(DEFAULT_EVENTER, "epoll")
374         have_epoll=1
375 fi
376
377 AC_CACHE_CHECK([for kqueue support], ac_cv_have_kqueue, [
378         AC_TRY_LINK(
379                 [ #include <sys/types.h> ],
380                 [ u_int a; a = kqueue(); ],
381                 [ ac_cv_have_kqueue="yes" ],
382                 [ ac_cv_have_kqueue="no" ]
383         )
384 ])
385 if test "x$ac_cv_have_kqueue" = "xyes" ; then
386         AC_DEFINE(HAVE_KQUEUE)
387         EVENTER_OBJS="$EVENTER_OBJS eventer_kqueue_impl.o"
388         AC_DEFINE_UNQUOTED(DEFAULT_EVENTER, "kqueue")
389         have_kqueue=1
390 fi
391
392 AC_CACHE_CHECK([for Solaris ports support], ac_cv_have_ports, [
393         AC_TRY_LINK(
394                 [ #include <port.h> ],
395                 [ u_int a; a = port_create(); ],
396                 [ ac_cv_have_ports="yes" ],
397                 [ ac_cv_have_ports="no" ]
398         )
399 ])
400 if test "x$ac_cv_have_ports" = "xyes" ; then
401         AC_DEFINE(HAVE_PORTS)
402         EVENTER_OBJS="$EVENTER_OBJS eventer_ports_impl.o"
403         AC_DEFINE_UNQUOTED(DEFAULT_EVENTER, "ports")
404         have_ports=1
405 fi
406
407 AC_SUBST(EVENTER_OBJS)
408
409 AC_CACHE_CHECK([for posix_readdir_r], ac_cv_have_posix_readdir_r, [
410         AC_TRY_COMPILE(
411                 [ #include <dirent.h> ],
412                 [ struct dirent *dep, de; readdir_r("/", &de, &dep); ],
413                 [ ac_cv_have_posix_readdir_r="yes" ],
414                 [ ac_cv_have_posix_readdir_r="no" ]
415         )
416 ])
417 if test "x$ac_cv_have_posix_readdir_r" = "xyes" ; then
418         AC_DEFINE(HAVE_POSIX_READDIR_R)
419         have_posix_readdir_r=1
420 fi
421
422 AC_CACHE_CHECK([for u_int type], ac_cv_have_u_int, [
423         AC_TRY_COMPILE(
424                 [ #include <sys/types.h> ],
425                 [ u_int a; a = 1;],
426                 [ ac_cv_have_u_int="yes" ],
427                 [ ac_cv_have_u_int="no" ]
428         )
429 ])
430 if test "x$ac_cv_have_u_int" = "xyes" ; then
431         AC_DEFINE(HAVE_U_INT)
432         have_u_int=1
433 fi
434
435 AC_CACHE_CHECK([for intXX_t types], ac_cv_have_intxx_t, [
436         AC_TRY_COMPILE(
437                 [ #include <sys/types.h> ],
438                 [ int8_t a; int16_t b; int32_t c; a = b = c = 1;],
439                 [ ac_cv_have_intxx_t="yes" ],
440                 [ ac_cv_have_intxx_t="no" ]
441         )
442 ])
443 if test "x$ac_cv_have_intxx_t" = "xyes" ; then
444         AC_DEFINE(HAVE_INTXX_T)
445         have_intxx_t=1
446 fi
447        
448 AC_CACHE_CHECK([for int64_t type], ac_cv_have_int64_t, [
449         AC_TRY_COMPILE(
450                 [ #include <sys/types.h> ],
451                 [ int64_t a; a = 1;],
452                 [ ac_cv_have_int64_t="yes" ],
453                 [ ac_cv_have_int64_t="no" ]
454         )
455 ])
456 if test "x$ac_cv_have_int64_t" = "xyes" ; then
457         AC_DEFINE(HAVE_INT64_T)
458         have_int64_t=1
459 fi
460        
461 AC_CACHE_CHECK([for u_intXX_t types], ac_cv_have_u_intxx_t, [
462         AC_TRY_COMPILE(
463                 [ #include <sys/types.h> ],
464                 [ u_int8_t a; u_int16_t b; u_int32_t c; a = b = c = 1;],
465                 [ ac_cv_have_u_intxx_t="yes" ],
466                 [ ac_cv_have_u_intxx_t="no" ]
467         )
468 ])
469 if test "x$ac_cv_have_u_intxx_t" = "xyes" ; then
470         AC_DEFINE(HAVE_U_INTXX_T)
471         have_u_intxx_t=1
472 fi
473
474 AC_CACHE_CHECK([for u_int64_t types], ac_cv_have_u_int64_t, [
475         AC_TRY_COMPILE(
476                 [ #include <sys/types.h> ],
477                 [ u_int64_t a; a = 1;],
478                 [ ac_cv_have_u_int64_t="yes" ],
479                 [ ac_cv_have_u_int64_t="no" ]
480         )
481 ])
482 if test "x$ac_cv_have_u_int64_t" = "xyes" ; then
483         AC_DEFINE(HAVE_U_INT64_T)
484         have_u_int64_t=1
485 fi
486
487 if (test -z "$have_u_intxx_t" || test -z "$have_intxx_t" && \
488            test "x$ac_cv_header_sys_bitypes_h" = "xyes")
489 then
490         AC_MSG_CHECKING([for intXX_t and u_intXX_t types in sys/bitypes.h])
491         AC_TRY_COMPILE(
492                 [
493 #include <sys/bitypes.h>
494                 ],
495                 [
496                         int8_t a; int16_t b; int32_t c;
497                         u_int8_t e; u_int16_t f; u_int32_t g;
498                         a = b = c = e = f = g = 1;
499                 ],
500                 [
501                         AC_DEFINE(HAVE_U_INTXX_T)
502                         AC_DEFINE(HAVE_INTXX_T)
503                         AC_MSG_RESULT(yes)
504                 ],
505                 [AC_MSG_RESULT(no)]
506         )
507 fi
508
509 if test -z "$have_u_intxx_t" ; then
510         AC_CACHE_CHECK([for uintXX_t types], ac_cv_have_uintxx_t, [
511                 AC_TRY_COMPILE(
512                         [
513 #include <sys/types.h>
514                         ],
515                         [ uint8_t a; uint16_t b; uint32_t c; a = b = c = 1; ],
516                         [ ac_cv_have_uintxx_t="yes" ],
517                         [ ac_cv_have_uintxx_t="no" ]
518                 )
519         ])
520         if test "x$ac_cv_have_uintxx_t" = "xyes" ; then
521                 AC_DEFINE(HAVE_UINTXX_T)
522         fi
523 fi
524
525 AC_CACHE_CHECK([for socklen_t], ac_cv_have_socklen_t, [
526         AC_TRY_COMPILE(
527                 [
528 #include <sys/types.h>
529 #include <sys/socket.h>
530                 ],
531                 [socklen_t foo; foo = 1235;],
532                 [ ac_cv_have_socklen_t="yes" ],
533                 [ ac_cv_have_socklen_t="no" ]
534         )
535 ])
536 if test "x$ac_cv_have_socklen_t" = "xyes" ; then
537         AC_DEFINE(HAVE_SOCKLEN_T)
538 fi
539
540 AC_CACHE_CHECK([for size_t], ac_cv_have_size_t, [
541         AC_TRY_COMPILE(
542                 [
543 #include <sys/types.h>
544                 ],
545                 [ size_t foo; foo = 1235; ],
546                 [ ac_cv_have_size_t="yes" ],
547                 [ ac_cv_have_size_t="no" ]
548         )
549 ])
550 if test "x$ac_cv_have_size_t" = "xyes" ; then
551         AC_DEFINE(HAVE_SIZE_T)
552 fi
553
554 AC_CACHE_CHECK([for ssize_t], ac_cv_have_ssize_t, [
555         AC_TRY_COMPILE(
556                 [
557 #include <sys/types.h>
558                 ],
559                 [ ssize_t foo; foo = 1235; ],
560                 [ ac_cv_have_ssize_t="yes" ],
561                 [ ac_cv_have_ssize_t="no" ]
562         )
563 ])
564 if test "x$ac_cv_have_ssize_t" = "xyes" ; then
565         AC_DEFINE(HAVE_SSIZE_T)
566 fi
567
568 AC_SUBST(BUILD_MODULES)
569
570 docdir="docs"
571 mansubdir="man"
572 AC_SUBST(docdir)
573 AC_SUBST(mansubdir)
574 SHCFLAGS="$PICFLAGS $CFLAGS"
575 AC_SUBST(SHCFLAGS)
576
577 AC_MSG_CHECKING([Resolving libexec path...])
578 fullpath=$libexecdir
579 while test "x$temppath" != "x$fullpath" ; do
580   temppath=$fullpath
581   fullpath=`eval echo ${fullpath}`
582 done
583 fullpath=`echo $fullpath | sed "s~NONE~$ac_default_prefix~"`
584 AC_MSG_RESULT([$fullpath/noit])
585 AC_DEFINE_UNQUOTED(MODULES_DIR, "${fullpath}/noit")
586 MODULES_DIR=${fullpath}/noit
587 AC_SUBST(MODULES_DIR)
588
589 AC_MSG_CHECKING([Resolving sysconfdir path...])
590 fullpath=$sysconfdir
591 while test "x$temppath" != "x$fullpath" ; do
592   temppath=$fullpath
593   fullpath=`eval echo ${fullpath}`
594 done
595 fullpath=`echo $fullpath | sed "s~NONE~$ac_default_prefix~"`
596 AC_MSG_RESULT([$fullpath])
597 AC_DEFINE_UNQUOTED(ETC_DIR, "${fullpath}")
598 ETC_DIR=${fullpath}
599 AC_SUBST(ETC_DIR)
600
601
602 AC_OUTPUT([
603 Makefile
604 src/Makefile
605 src/eventer/Makefile
606 src/jlog/Makefile
607 src/jlog/perl/Makefile.PL
608 src/udns/Makefile
609 src/man/Makefile
610 src/modules/Makefile
611 src/modules-lua/Makefile
612 src/utils/Makefile
613 src/noitedit/Makefile
614 src/lua/Makefile
615 src/java/Makefile
616 src/java/run-iep.sh
617 sql/Makefile
618 test/Makefile
619 ])
Note: See TracBrowser for help on using the browser.